Dynamics 365 Business Central: How to set the default view/layout for a list page (Predefined List View)

Hi, Readers.
Views in Dynamics 365 Business Central are used on list pages to define a different view of the data on a given page. A view offers:

• Filtering on multiple table fields on the source table defined for the page.
• Sorting of the data on multiple table fields, but only in one direction; either ascending or descending.
• Layout changes, modifying page columns, moving them, etc.

When you have set a filter on a list and you want to keep the filter for later, you can save it as a view. More about To save a view in MS Docs.

PS: Dynamics 365 Business Central: Shared layout view and Detached layout view (Unique layouts of the columns on a list)

This is a great feature, but there has always been a problem. No matter how many views you create, or which view you stay on when you close the page, when you open the page again, the All view will be opened by default.

So can we specify the default view? I always thought this was impossible. However, I learned a method in the Dynamics 365 Community last week. In this post, I will briefly share it with you, hoping it will be helpful. More details: Page Predefined Views

First, let me briefly explain why I think it is not possible.

About where are list views saved?
Similarly to hiding a field or reordering your navigation menu, list views are a part of user personalization and are stored in the database. Clearing all personalization on a list will also permanently remove your personal views and clear other personalization such as reordering of views. For more information, see Personalize your workspace.

But in the world of Cloud (SaaS), we cannot directly access the database, so we cannot find this part of the data.

The second problem is that in the Web Client URL, there is no URL Parameters about List View, more details:

PS: Dynamics 365 Business Central: Filtering Data by the Web Client URL

So I think this can’t be done, but in fact the Web Client URL contains the “view” parameter. (Version: W1 23.4 (Platform 23.0.16474.0 + Application 23.4.15643.15715))
Let’s see a few examples,
Item List (31, List):
All (Default view): No “view” parameter.

https://businesscentral.dynamics.com/c8558e71-6ad8-4fcd-9f29-3ca165b41bbe/Sandbox234?company=My%20Company&page=31&dc=0&bookmark=13_GwAAAAJ7BDEAMAAwADM

Test01:

https://businesscentral.dynamics.com/c8558e71-6ad8-4fcd-9f29-3ca165b41bbe/Sandbox234?company=My%20Company&view=aa49406f-6f68-4565-b857-496faa0e77aa_Test0112223&page=31&filter=Item.%27No.%27%20IS%20%271800-S..1900-S%27&dc=0&bookmark=17_GwAAAAJ7_zEAOAA5ADYALQBT

Test02:

https://businesscentral.dynamics.com/c8558e71-6ad8-4fcd-9f29-3ca165b41bbe/Sandbox234?company=My%20Company&sk=SxsB0m7JFXprxyf74oyPTw&view=aa49406f-6f68-4565-b857-496faa0e77aa_Test0221625&node=0000233e-fd3e-0000-0c46-0f00836bd2d2&page=31&filter=Item.%27No.%27%20IS%20%271900-S..%27&dc=0&bookmark=17_GwAAAAJ7_zEAOQAwADAALQBT

ZYTest:

https://businesscentral.dynamics.com/c8558e71-6ad8-4fcd-9f29-3ca165b41bbe/Sandbox234?company=My%20Company&sk=SxsB0m7JFXprxyf74oyPTw&view=aa49406f-6f68-4565-b857-496faa0e77aa_ZYTest00045&node=0000233e-fd3e-0000-0c46-0f00836bd2d2&page=31&filter=Item.Inventory%20IS%20%27%3e0%27&dc=0&bookmark=17_GwAAAAJ7_zEAOAA5ADYALQBT

Customer Ledger Entries (25, List):
Invoice:

https://businesscentral.dynamics.com/c8558e71-6ad8-4fcd-9f29-3ca165b41bbe/Sandbox234?company=My%20Company&sk=SxsB0m7JFXprxyf74oyPTw&view=aa49406f-6f68-4565-b857-496faa0e77aa_Invoice07400&page=25&filter=%27Cust.%20Ledger%20Entry%27.%27Document%20Type%27%20IS%20%272%27&dc=0&bookmark=C_FQAAAACHqQY

Payment:

https://businesscentral.dynamics.com/c8558e71-6ad8-4fcd-9f29-3ca165b41bbe/Sandbox234?company=My%20Company&sk=SxsB0m7JFXprxyf74oyPTw&view=aa49406f-6f68-4565-b857-496faa0e77aa_Payment57019&page=25&filter=%27Cust.%20Ledger%20Entry%27.%27Document%20Type%27%20IS%20%271%27&dc=0&bookmark=C_FQAAAACHgAY

PS:
1. If the view name contains characters that cannot be recognized by the web browser, they will be automatically encoded.
More details: Dynamics 365 Business Central: How to encode and decode URL/HTML (UrlEncode, UrlDecode, HtmlEncode, and HtmlDecode)

https://businesscentral.dynamics.com/c8558e71-6ad8-4fcd-9f29-3ca165b41bbe/Sandbox234?company=My%20Company&sk=SxsB0m7JFXprxyf74oyPTw&view=aa49406f-6f68-4565-b857-496faa0e77aa_Payment%20%5bCopy%5d13152&page=25&filter=%27Cust.%20Ledger%20Entry%27.%27Document%20Type%27%20IS%20%271%27&dc=0&bookmark=C_FQAAAACHgAY

2. Even if you rename the view on the page, the original name is still saved in the URL. So the view ID will not change.

3. We can use the following URL to directly open the specified view.

https://businesscentral.dynamics.com/c8558e71-6ad8-4fcd-9f29-3ca165b41bbe/Sandbox234?company=My%20Company&view=aa49406f-6f68-4565-b857-496faa0e77aa_Test0112223&page=31

Test video: So you only need to ask the customer to open BC from the URL, so that the required view can be opened directly.

Here are some additional conclusions
1. The id of each view is fixed (The view must be opened first to get the id from the URL)
2. It consists of the “Page id” + “_” + “View Name” + “Random five numbers”
3. The “Page id” of each page is the same

So if customized, we can simply do the following.

Test video: This method is to open a new tab.

Source code: Github (Please note that the source code is for reference only, you can improve it according to your own needs)

pageextension 50120 CustomerListExt extends "Customer List"
{
    actions
    {
        addafter(ApplyTemplate)
        {
            action("Item list - Test01")
            {
                ApplicationArea = All;
                Caption = 'Item list - Test01';
                Image = Open;
                Promoted = true;
                PromotedCategory = Process;

                trigger OnAction()
                begin
                    OpenSpecifiedView('aa49406f-6f68-4565-b857-496faa0e77aa_Test0112223', Page::"Item List");
                end;
            }
            action("Item list - Test02")
            {
                ApplicationArea = All;
                Caption = 'Item list - Test02';
                Image = Open;
                Promoted = true;
                PromotedCategory = Process;

                trigger OnAction()
                begin
                    OpenSpecifiedView('aa49406f-6f68-4565-b857-496faa0e77aa_Test0221625', Page::"Item List");
                end;
            }
            action("Item list - ZYTest")
            {
                ApplicationArea = All;
                Caption = 'Item list - ZYTest';
                Image = Open;
                Promoted = true;
                PromotedCategory = Process;

                trigger OnAction()
                begin
                    OpenSpecifiedView('aa49406f-6f68-4565-b857-496faa0e77aa_ZYTest00045', Page::"Item List");
                end;
            }
            action("Customer Ledger Entries - Invoice")
            {
                ApplicationArea = All;
                Caption = 'Customer Ledger Entries - Invoice';
                Image = Open;
                Promoted = true;
                PromotedCategory = Process;

                trigger OnAction()
                begin
                    OpenSpecifiedView('aa49406f-6f68-4565-b857-496faa0e77aa_Invoice07400', Page::"Customer Ledger Entries");
                end;
            }
        }
    }

    local procedure OpenSpecifiedView(ViewID: Text; PageID: Integer)
    var
        DefaultView: Text;
        URL: Text;
    begin
        DefaultView := '&view=' + ViewID;
        URL := GetUrl(CurrentClientType, CompanyName, ObjectType::Page, PageID) + DefaultView;
        Hyperlink(URL);
    end;
}

If you need to open in the same window/current session, consider the following solution, which is a little more complicated.
Dynamics 365 Business Central: Using Hyperlink() Method to open a URL in a current session without opening a new tab in the browser

Test video:

Source code: Github (Please note that the source code is for reference only, you can improve it according to your own needs)

pageextension 50120 CustomerListExt extends "Customer List"
{
    actions
    {
        addafter(ApplyTemplate)
        {
            action("Item list - Test01")
            {
                ApplicationArea = All;
                Caption = 'Item list - Test01';
                Image = Open;
                Promoted = true;
                PromotedCategory = Process;

                trigger OnAction()
                begin
                    OpenSpecifiedView('aa49406f-6f68-4565-b857-496faa0e77aa_Test0112223', Page::"Item List");
                end;
            }
            action("Item list - Test02")
            {
                ApplicationArea = All;
                Caption = 'Item list - Test02';
                Image = Open;
                Promoted = true;
                PromotedCategory = Process;

                trigger OnAction()
                begin
                    OpenSpecifiedView('aa49406f-6f68-4565-b857-496faa0e77aa_Test0221625', Page::"Item List");
                end;
            }
            action("Item list - ZYTest")
            {
                ApplicationArea = All;
                Caption = 'Item list - ZYTest';
                Image = Open;
                Promoted = true;
                PromotedCategory = Process;

                trigger OnAction()
                begin
                    OpenSpecifiedView('aa49406f-6f68-4565-b857-496faa0e77aa_ZYTest00045', Page::"Item List");
                end;
            }
            action("Customer Ledger Entries - Invoice")
            {
                ApplicationArea = All;
                Caption = 'Customer Ledger Entries - Invoice';
                Image = Open;
                Promoted = true;
                PromotedCategory = Process;

                trigger OnAction()
                begin
                    OpenSpecifiedView('aa49406f-6f68-4565-b857-496faa0e77aa_Invoice07400', Page::"Customer Ledger Entries");
                end;
            }
        }
    }

    local procedure OpenSpecifiedView(ViewID: Text; PageID: Integer)
    var
        DefaultView: Text;
        URL: Text;
        ZYHyperLink: Page "ZY HyperLink";
    begin
        DefaultView := '&view=' + ViewID;
        URL := GetUrl(CurrentClientType, CompanyName, ObjectType::Page, PageID) + DefaultView;
        ZYHyperLink.SetURL(URL);
        ZYHyperLink.Run();
    end;
}

page 50111 "ZY HyperLink"
{
    Extensible = false;
    Caption = 'HyperLink';
    Editable = false;
    PageType = Card;

    layout
    {
        area(content)
        {
            group(Control5)
            {
                ShowCaption = false;
            }
            usercontrol(WebPageViewer; "Microsoft.Dynamics.Nav.Client.WebPageViewer")
            {
                ApplicationArea = All;

                trigger ControlAddInReady(callbackUrl: Text)
                begin
                    CurrPage.WebPageViewer.Navigate(URL);
                end;

                trigger Callback(data: Text)
                begin
                    CurrPage.Close();
                end;
            }
        }
    }

    var
        URL: Text;

    procedure SetURL(NavigateToURL: Text)
    begin
        URL := NavigateToURL;
    end;
}

Great, give it a try!!!😁

END

Hope this will help.

Thanks for reading.

ZHU