Dynamics 365 Business Central: SessionSettings Data Type (A complex data type)

Hi, Readers.
Today, I would like to talk about SessionSettings Data Type in Business Central.

SessionSettings data type is a complex data type for passing user personalization settings for a client session as an object. The object contains properties that correspond to the fields in the system table 2000000073 User Personalization, including: App ID, Company, Language ID, Locale ID, Profile ID, Scope, and Time Zone.

Table 2000000073 “User Personalization”:

You can force Business Central to run the “User Personalization” table by adding the ?table=2000000073 parameter to the URL, such as in the following example: 
https://businesscentral.dynamics.com/d8f36038-1f93-4543-affc-5dc92b6ee871/Sandbox?table=2000000073

Sample Data:

You can use the AL methods of the SessionSettings data type to get, set, and send the user personalization settings for the current client session.

The following methods are available on instances of the SessionSettings data type:

Next, let us try it.

1. Get the user personalization settings

SessionSettings.Init Method: Populates the instance of a SessionsSettings with the current client user’s personalization properties (such as Profile ID and Company) that are stored in the database.

Syntax: SessionSettings.Init()

The method gets the data from the following fields in system table 2000000073 User Personalization: App ID, Company, Language ID, Locale ID, Profile ID, Scope, and Time Zone. In the SessionSettings object, the data is stored in properties that correspond to the fields of the system table.

After you call the Init method, you can get the values in the object by calling the following methods:

• Company
• LanguageId
• LocalId method
• ProfileAppId
• ProfileId
• ProfileSystemScope
• TimeZone

Let’s see a simple example:

Test Video:

2. Set the user personalization settings

SessionSettings.RequestSessionUpdate Method: Passes a SessionSettings object to the client to request a new session that uses the user personalization properties that are set in the object. The current client session is abandoned and a new session is started.

Syntax: SessionSettings.RequestSessionUpdate(saveSettings: Boolean)

saveSettings: Boolean: Specifies whether to save the personalization properties in the SessionSettings object to the table 2000000073 User Personalization in the database for the current client user. true saves the settings; false does not. If you set this parameter to true, before sending the request to the client, the server instance will store the property values of the SessionSettings object to the corresponding fields in the table 2000000073 User Personalization. If you set this to false, when the new client session is closed, the next time the user signs in, the session will return to the previous personalization settings. This enables you to use the SessionSettings object to temporarily change the personalization settings for the current session.

Let’s see a simple example: This example uses the Init method to create a SessionSettings object that includes the current client user’s personalization settings from the database, and then uses the LanguageId method and LocaleId method to set the new language and region.

Note: The Init method is useful before calling the RequestSessionUpdate method to ensure that all properties are initialized before sending the request to the server instance to start a new client session.

Test Video:

You can refer to the above method to do a quick switch between Company, Profile ID, Time Zone, etc.

Source Code:

codeunit 50100 GetSessionInfo
{
    trigger OnRun()
    var
        MySessionSettings: SessionSettings;
        Company: Text[30];
        LanguageID: Integer;
        LocalID: Integer;
        ProfileAppID: Guid;
        ProfileID: Code[30];
        ProfileSystemScope: Boolean;
        Timezone: Text[180];
        Msg: Label 'The Company is ''%1''.\The LanguageID is ''%2''.\The LocalID is ''%3''.\The ProfileAppID is ''%4''.\The ProfileID is ''%5''.\The ProfileSystemScope is ''%6''.\The Timezone is ''%7''.\';
    begin
        MySessionSettings.Init();
        Company := MySessionSettings.Company;
        LanguageID := MySessionSettings.LanguageId;
        LocalID := MySessionSettings.LocaleId;
        ProfileAppID := MySessionSettings.ProfileAppId;
        ProfileID := MySessionSettings.ProfileId;
        ProfileSystemScope := MySessionSettings.ProfileSystemScope;
        Timezone := MySessionSettings.TimeZone;
        Message(Msg, Company, LanguageID, LocalID, ProfileAppID, ProfileID, ProfileSystemScope, Timezone);
    end;
}

codeunit 50101 SessionUpdateChangeToJapanese
{
    trigger OnRun()
    var
        MySessionSettings: SessionSettings;
    begin
        MySessionSettings.Init();
        MySessionSettings.LanguageId(1041);
        MySessionSettings.LocaleId(1041);
        MySessionSettings.RequestSessionUpdate(true);
    end;
}

codeunit 50102 SessionUpdateChangeToEnglish
{
    trigger OnRun()
    var
        MySessionSettings: SessionSettings;
    begin
        MySessionSettings.Init();
        MySessionSettings.LanguageId(1033);
        MySessionSettings.LocaleId(1033);
        MySessionSettings.RequestSessionUpdate(true);
    end;
}

pageextension 50136 BusinessManagerRCExt extends "Business Manager Role Center"
{
    actions
    {
        addafter(Action41)
        {
            group("ZY New Menu")
            {
                Caption = 'ZY New Menu';

                action("GetSessionInfo")
                {
                    ApplicationArea = Basic, Suite;
                    Caption = 'Get Session Info';
                    Image = Change;
                    RunObject = codeunit GetSessionInfo;
                }

                action("ChangeToJapanese")
                {
                    ApplicationArea = Basic, Suite;
                    Caption = 'Change to Japanese';
                    Image = Change;
                    RunObject = codeunit SessionUpdateChangeToJapanese;
                }
                action("ChangeToEnglish")
                {
                    ApplicationArea = Basic, Suite;
                    Caption = 'Change to English';
                    Image = Change;
                    RunObject = codeunit SessionUpdateChangeToEnglish;
                }
            }
        }
    }
}

Find out more about SessionSettings Data Type from Microsoft Docs.

END

Hope this will help.

Thanks for reading.

ZHU