Dynamics 365 Business Central: How to convert Text to Hexadecimal in AL

Hi, Readers.
Today I would like to talk about how to convert Text to Hexadecimal in AL.
The hexadecimal number system is a type of number system, that has a base value equal to 16. Hexadecimal numbers are represented by only 16 symbols. These symbols or values are 0, 1, 2, 3, 4, 5, 6, 7, 8, 9, A, B, C, D, E and F.
Let’s look at a simple example, here is a tool I searched on Google.
Text To Hex: Business Central => 42 75 73 69 6E 65 73 73 20 43 65 6E 74 72 61 6C

How is this done? In simple terms, it requires four steps.

1. Get character
2. Get ASCII code of character
3. Convert decimal to hex byte
4. Continue with next character

Regarding Steps 1 and 2, we have mentioned them before when discussing how to extract characters from a string (indexing with []). For example,

Business Central => 66 117 115 105 110 101 115 115 32 67 101 110 116 114 97 108

I found some relevant datasheets in MS Learn (Docs). (Although there are not Business Central documents)
Character set (0 – 127): 7 bit

PS: The values with blanks are control characters, not characters displayed or printed by Windows.

Character set (128 – 255):

PS:
1. Character 160 is a no-break space. Character 173 is a soft hyphen. Some characters aren’t supported by Microsoft Windows (characters 129, 141, 143, 144, and 157).

2. The values in the table are the Windows default. However, values in the ANSI character set above 127 are determined by the code page specific to your operating system.

Then convert it to hexadecimal, so the complete process is as follows:

• B => 66 = 4*16¹+2*16⁰ = 42
• u => 117 = 7*16¹+5*16⁰ = 75
• s => 115 = 7*16¹+3*16⁰ = 73
• i => 105 = 6*16¹+9*16⁰ = 69
• n => 110 = 6*16¹+14*16⁰ = 6E
• e => 101 = 6*16¹+5*16⁰ = 65
• s => 115 = 7*16¹+3*16⁰ = 73
• s => 115 = 7*16¹+3*16⁰ = 73
• [space] => 32 = 2*16¹+0*16⁰ = 20
• C => 67 = 4*16¹+3*16⁰ = 43
• e => 101 = 6*16¹+5*16⁰ = 65
• n => 110 = 6*16¹+E*16⁰ = 6E
• t => 116 = 7*16¹+4*16⁰ = 74
• r => 114 = 7*16¹+2*16⁰ = 72
• a => 97 = 6*16¹+1*16⁰ = 61
• l => 108 = 6*16¹+12*16⁰ = 6C

The next step is how to implement it in AL.
The first approach is to do all the coding yourself, which is also a practice that comes from the NAV.

Source code: Github (Please note that the source code is for reference only, you can improve it according to your own needs)

page 50200 "Convert Text To Hexadecimal"
{
    PageType = Card;
    ApplicationArea = All;
    UsageCategory = Administration;

    layout
    {
        area(Content)
        {
            group(Input)
            {
                field(InputText; InputText)
                {
                    Caption = 'Input Text';
                    ApplicationArea = All;
                    trigger OnValidate()
                    begin
                        if InputText = '' then
                            Hexadecimal := '';
                        Hexadecimal := ConvertTextToHexadecimal(InputText);
                    end;
                }
            }
            group(Result)
            {
                field(Hexadecimal; Hexadecimal)
                {
                    Caption = 'Hexadecimal';
                    ApplicationArea = All;
                    Editable = false;
                }
            }
        }
    }
    var
        InputText: Text;
        Hexadecimal: Text;

    local procedure ConvertTextToHexadecimal(Input: Text) Output: Text
    var
        i: Integer;
        CharNo: Integer;
        HexLeft: Integer;
        HexRight: Integer;
    begin
        for i := 1 to StrLen(Input) do begin
            CharNo := Input[i];
            HexLeft := Round(CharNo / 16, 1, '<');
            HexRight := CharNo mod 16;
            Output += HexValue(HexLeft) + HexValue(HexRight);
        end;
    end;

    local procedure HexValue(Value: Integer): Text
    begin
        case Value of
            0 .. 9:
                exit(Format(Value));
            10:
                exit('A');
            11:
                exit('B');
            12:
                exit('C');
            13:
                exit('D');
            14:
                exit('E');
            15:
                exit('F');
        end;
    end;
}

There is actually a second way. In codeunit 10 “Type Helper”, you can find a method, procedure IntToHex.

    procedure IntToHex(IntValue: Integer): Text
    var
        DotNetIntPtr: DotNet IntPtr;
    begin
        DotNetIntPtr := DotNetIntPtr.IntPtr(IntValue);
        exit(DotNetIntPtr.ToString('X'));
    end;

Yes, we can simply use it.

Source code: Github (Please note that the source code is for reference only, you can improve it according to your own needs)

page 50200 "Convert Text To Hexadecimal"
{
    PageType = Card;
    ApplicationArea = All;
    UsageCategory = Administration;

    layout
    {
        area(Content)
        {
            group(Input)
            {
                field(InputText; InputText)
                {
                    Caption = 'Input Text';
                    ApplicationArea = All;
                    trigger OnValidate()
                    begin
                        if InputText = '' then
                            Hexadecimal := '';
                        Hexadecimal := ConvertTextToHexadecimal(InputText);
                    end;
                }
            }
            group(Result)
            {
                field(Hexadecimal; Hexadecimal)
                {
                    Caption = 'Hexadecimal';
                    ApplicationArea = All;
                    Editable = false;
                }
            }
        }
    }
    var
        InputText: Text;
        Hexadecimal: Text;

    local procedure ConvertTextToHexadecimal(Input: Text) Output: Text
    var
        i: Integer;
        CharNo: Integer;
        TypeHelper: Codeunit "Type Helper";
        Str: Text;
    begin
        for i := 1 to StrLen(Input) do begin
            CharNo := Input[i];
            Str := TypeHelper.IntToHex(CharNo);
            Output += Str;
        end;
    end;
}

Great. Give it a try!!!😁

PS: Dynamics 365 Business Central: How to prohibit users from entering illegal characters such as emoji, Hiragana, kanji, etc.

END

Hope this will help.

Thanks for reading.

ZHU