Dynamics 365 Business Central: Generate barcode through external services/APIs (Telepen, Swiss QR Code, QR codes with colors, images or text……)

Hi, Readers.
The barcode functionality lets you convert an alphanumeric value in a report dataset into a barcode on a generated report. The functionality is provided by the Barcode module of the System Application. The module includes the objects and tools that you need to add barcodes to reports. More details:

• Business Central 2021 wave 2 (BC19.1): Using 2D barcodes Font in BC Online/SaaS (Aztec, Data Matrix, Maxi Code, PDF417, QR-Code)

• Dynamics 365 Business Central 2021 release wave 1 (BC18): Use one-dimensional barcodes in reports (Business Central online)

This is a standard function provided by Microsoft. We can simply add it in the extension using AL. However, if the customer requires a QR code in a special format, such as a special size, background color, etc., the standard cannot do it. For example,

At this time we can use some external services/APIs. Here is the API I used for this test:
QR Code API: QuickChart supports QR code generation. Generate a QR code like this: https://quickchart.io/qr?text=Here’s my text

QR code parameters: Build your customized QR code using the following query parameters. You may also use the web-based QR code builder.

Here’s the same code as above but URL encoded with slimmer margins, more error protection, colors, and in SVG format: https://quickchart.io/qr?text=Here’s%20my%20text&dark=f00&light=0ff&ecLevel=Q&format=svg

Let’s look at a simple example of utilizing this API from AL: Generate a QR Code from the Item Number and Item Description, and then save the QR Code in the Item Picture. (Of course, you can also create a new media field or blob field to save the QR Code)

In addition, we can also add an image to the QR Code, which is also impossible in the standard. (Only the URL is different)

BarcodeAPIURL := 'https://quickchart.io/qr?text=' + Rec."No." + '_' + Rec.Description + '&centerImageUrl=https://yzhums.com/wp-content/uploads/2025/05/Snipaste_2025-05-19_14-42-11.png';

And we can also add some instructions below the QR Code.

BarcodeAPIURL := 'https://quickchart.io/qr?text=' + Rec."No." + '_' + Rec.Description + '&caption=TextBelowQr&captionFontFamily=mono&captionFontSize=20'; //Text below QR code

Source code: Github (Please note that the source code is for reference only, you can improve it according to your own needs)

pageextension 50112 ItemCardExt extends "Item Card"
{
    actions
    {
        addfirst(processing)
        {
            action(GenerateQRCode)
            {
                ApplicationArea = All;
                Caption = 'Generate QR Code';
                Image = CreateDocument;
                Promoted = true;
                PromotedCategory = Process;
                trigger OnAction()
                var
                    BarcodeAPIURL: Text;
                    Client: HttpClient;
                    HttpResponseMsg: HttpResponseMessage;
                    HttpRequestMsg: HttpRequestMessage;
                    InS: InStream;
                    OverrideImageQst: Label 'The existing picture will be replaced. Do you want to continue?';
                    MustSpecifyDescriptionErr: Label 'You must add a description to the item before you can import a picture.';
                    FileName: Text;
                begin
                    if Rec.Description = '' then
                        Error(MustSpecifyDescriptionErr);
                    if Rec.Picture.Count > 0 then
                        if not Confirm(OverrideImageQst) then
                            Error('');
                    FileName := Rec.Description + '.png';
                    //BarcodeAPIURL := 'https://quickchart.io/qr?text=' + Rec."No." + '_' + Rec.Description + '&dark=f00&light=0ff&ecLevel=Q&format=png';// Here's the same code as above but URL encoded with slimmer margins, more error protection, colors, and in png format
                    BarcodeAPIURL := 'https://quickchart.io/qr?text=' + Rec."No." + '_' + Rec.Description + '&centerImageUrl=https://yzhums.com/wp-content/uploads/2025/05/Snipaste_2025-05-19_14-42-11.png';// Add an images in QR codes
                    //BarcodeAPIURL := 'https://quickchart.io/qr?text=' + Rec."No." + '_' + Rec.Description + '&caption=TextBelowQr&captionFontFamily=mono&captionFontSize=20'; //Text below QR code
                    HttpRequestMsg.SetRequestUri(BarcodeAPIURL);
                    if Client.Send(HttpRequestMsg, HttpResponseMsg) then begin
                        if HttpResponseMsg.IsSuccessStatusCode() then begin
                            HttpResponseMsg.Content.ReadAs(InS);
                            Clear(Rec.Picture);
                            Rec.Picture.ImportStream(InS, FileName);
                            Rec.Modify(true);
                        end;
                    end else
                        Error('Failed to send request to the API.');
                end;
            }
        }
    }
}

Of course, we can also generate other types of barcodes through external services/APIs.

Barcode API: https://quickchart.io/barcode?type=datamatrix&text=foo
Supported Parameters:​

Supported Barcode Types: Please note that some barcodes have limitations such as length or only support numbers. You can test it by url first, for example, https://quickchart.io/barcode?type=datamatrix&text=Custom%20Size&width=300&height=300

Let’s look at another simple example, users can select one of five barcode types (‘QR Code, Data Matrix, Aztec, Telepen, Swiss QR Code’) and save it in the item picture.

Test video:

Source code: Github (Please note that the source code is for reference only, you can improve it according to your own needs)

pageextension 50112 ItemCardExt extends "Item Card"
{
    actions
    {
        addfirst(processing)
        {
            action(GenerateQRCode)
            {
                ApplicationArea = All;
                Caption = 'Generate QR Code';
                Image = CreateDocument;
                Promoted = true;
                PromotedCategory = Process;
                trigger OnAction()
                var
                    BarcodeAPIURL: Text;
                    Client: HttpClient;
                    HttpResponseMsg: HttpResponseMessage;
                    HttpRequestMsg: HttpRequestMessage;
                    InS: InStream;
                    OverrideImageQst: Label 'The existing picture will be replaced. Do you want to continue?';
                    MustSpecifyDescriptionErr: Label 'You must add a description to the item before you can import a picture.';
                    FileName: Text;
                    BarcodeTypes: Label 'QR Code, Data Matrix, Aztec, Telepen, Swiss QR Code';
                    Selection: Integer;
                begin
                    if Rec.Description = '' then
                        Error(MustSpecifyDescriptionErr);
                    if Rec.Picture.Count > 0 then
                        if not Confirm(OverrideImageQst) then
                            Error('');
                    FileName := Rec.Description + '.png';
                    Selection := StrMenu(BarcodeTypes);
                    case
                        Selection of
                        1:
                            BarcodeAPIURL := 'https://quickchart.io/barcode?type=' + 'qrcode' + '&text=' + Rec."No." + '_' + Rec.Description + '&width=200&height=200&format=png';
                        2:
                            BarcodeAPIURL := 'https://quickchart.io/barcode?type=' + 'datamatrix' + '&text=' + Rec."No." + '_' + Rec.Description + '&width=200&height=200&format=png';
                        3:
                            BarcodeAPIURL := 'https://quickchart.io/barcode?type=' + 'azteccode' + '&text=' + Rec."No." + '_' + Rec.Description + '&width=200&height=200&format=png';
                        4:
                            BarcodeAPIURL := 'https://quickchart.io/barcode?type=' + 'telepen' + '&text=' + Rec."No." + '_' + Rec.Description + '&width=200&height=200&format=png';
                        5:
                            BarcodeAPIURL := 'https://quickchart.io/barcode?type=' + 'swissqrcode' + '&text=' + Rec."No." + '_' + Rec.Description + '&format=png';
                    end;
                    HttpRequestMsg.SetRequestUri(BarcodeAPIURL);
                    if Client.Send(HttpRequestMsg, HttpResponseMsg) then begin
                        if HttpResponseMsg.IsSuccessStatusCode() then begin
                            HttpResponseMsg.Content.ReadAs(InS);
                            Clear(Rec.Picture);
                            Rec.Picture.ImportStream(InS, FileName);
                            Rec.Modify(true);
                        end;
                    end else
                        Error('Failed to send request to the API.');
                end;
            }
        }
    }
}

Very simple. You can also add a QR code to a report using the following methods.

• Dynamics 365 Business Central: How to add Media or MediaSet data type (Pictures) to a report
• How to generate QR code for Dynamics 365 Business Central Page URL (For example, embed the customer card URL in QR code)

Also, please note that some of these external services are not completely free, and you need to pay attention to the instructions on these websites. For example, QuickChart Pricing

You can also try other external services, such as the two below. If your country has better services, you can use them, not limited to those mentioned in this post. But please note that the structure and keywords of the URL may be different, the method is the same. Give it a try!!!😁

1. https://orcascan.com/guides/free-barcode-image-api-0e4a4fa6
2. https://barcode.tec-it.com/en/Code11?data=0123-4567

END

Hope this will help.

Thanks for reading.

ZHU